Re: [docbook-apps] Problem with draft and body start indent

["Bob Stayton" <bobs@sagehill.net>]

It is a bug.  This template sets the flow properties that includes that
body.start.indent.  It is matching on the non-draft page-master names, but
not the draft names:

<xsl:template name="set.flow.properties">
  <xsl:param name="element" select="local-name(.)"/>
  <xsl:param name="master-reference" select="''"/>

  <!-- This template is called after each <fo:flow> starts. -->
  <!-- Customize this template to set attributes on fo:flow -->

  <xsl:choose>
    <xsl:when test="$fop.extensions != 0 or $passivetex.extensions != 0">
      <!-- body.start.indent does not work well with these processors -->
    </xsl:when>
    <xsl:when test="$master-reference = 'body' or
                    $master-reference = 'lot' or
                    $master-reference = 'front' or
                    $element = 'preface' or
                    ($master-reference = 'back' and
                    $element = 'appendix')">
      <xsl:attribute name="start-indent">
        <xsl:value-of select="$body.start.indent"/>
      </xsl:attribute>
      <xsl:attribute name="end-indent">
        <xsl:value-of select="$body.end.indent"/>
      </xsl:attribute>
    </xsl:when>
  </xsl:choose>

</xsl:template>

The tests should really be:

    starts-with($master-reference, 'body') or etc.

I just checked in the fix, so the next snapshot should have it.  Or you can
add the fixed template to your customization layer.

Bob Stayton
Sagehill Enterprises
DocBook Consulting
bobs@sagehill.net


----- Original Message ----- 
From: "Bill Lawrence" <lawrence@mayaviz.com>
To: <docbook-apps@lists.oasis-open.org>
Sent: Wednesday, September 21, 2005 11:39 AM
Subject: [docbook-apps] Problem with draft and body start indent


> I've noticed that when I set draft mode to yes, I lose the left indent
> set through the body.start.indent parameter.  I've tried this in
> versions 1.68.1 and the current version of the XSL stylesheets.  Is this
> a bug, or is draft mode not supposed to honor page format settings?
>
> Thanks in advance,
>
> Bill Lawrence
>
>
>
> ---------------------------------------------------------------------
> To unsubscribe, e-mail: docbook-apps-unsubscribe@lists.oasis-open.org
> For additional commands, e-mail: docbook-apps-help@lists.oasis-open.org
>
>
>