[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [List Home]
Subject: Re: [docbook-apps] Re: xml:base and stylesheets
Mauritz Jeanson wrote:
> I found a problem with the latest stripns.xsl, I'm afraid.
>
> On Windows, saxon:systemId() returns this (as an example):
>
> file:/c:/doctypes/docbook/imgtest-ng.xml
>
> This results in the following xml:base attribute on the root element of the
> stripped document:
>
> /c:/doctypes/docbook/
>
> The leading slash is clearly not right.
> And if the leading slash wasn't there, would it really be a valid URI (since
> there is no 'file:///' prefix)?
Please try attached strpins.xsl. It should fix Windoze problem.
Jirka
--
------------------------------------------------------------------
Jirka Kosek e-mail: jirka@kosek.cz http://www.kosek.cz
------------------------------------------------------------------
Profesionální školení a poradenství v oblasti technologií XML.
Podívejte se na náš nově spuštěný web http://DocBook.cz
Podrobný přehled školení http://xmlguru.cz/skoleni/
------------------------------------------------------------------
Nejbližší termíny školení:
** XSLT 13.-16.3.2006 ** XML schémata 24.-26.4.2006 **
** DocBook 15.-17.5.2006 ** XSL-FO 12.-13.6.2006 **
------------------------------------------------------------------
http://xmlguru.cz Blog mostly about XML for English readers
------------------------------------------------------------------
<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
xmlns:ng="http://docbook.org/docbook-ng";
xmlns:db="http://docbook.org/ns/docbook";
xmlns:saxon="http://icl.com/saxon";
xmlns:exsl="http://exslt.org/common";
exclude-result-prefixes="db ng exsl saxon"
version='1.0'>
<!-- put an xml:base attribute on the root element -->
<xsl:template match="/*" mode="stripNS">
<xsl:choose>
<xsl:when test="self::ng:* or self::db:*">
<xsl:element name="{local-name(.)}">
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="not(@xml:base) and function-available('saxon:systemId')">
<xsl:variable name="base" select="saxon:systemId()"/>
<xsl:attribute name="xml:base">
<xsl:call-template name="systemIdToBaseURI">
<xsl:with-param name="systemId">
<!-- file: seems to confuse some processors. -->
<xsl:choose>
<!-- Windoze boxed are handles specially, they are confused without file -->
<xsl:when test="starts-with($base, 'file:/') and substring($base, 8, 1) = ':'">
<xsl:value-of select="concat('file:///', substring-after($base,'file:/'))"/>
</xsl:when>
<xsl:when test="starts-with($base, 'file:///')">
<xsl:value-of select="substring-after($base,'file://')"/>
</xsl:when>
<xsl:when test="starts-with($base, 'file://')">
<xsl:value-of select="substring-after($base,'file:/')"/>
</xsl:when>
<xsl:when test="starts-with($base, 'file:/')">
<xsl:value-of select="substring-after($base,'file:')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$base"/>
</xsl:otherwise>
</xsl:choose>
</xsl:with-param>
</xsl:call-template>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</xsl:element>
</xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="not(@xml:base) and function-available('saxon:systemId')">
<xsl:attribute name="xml:base">
<xsl:call-template name="systemIdToBaseURI">
<xsl:with-param name="systemId">
<xsl:choose>
<!-- file: seems to confuse some processors. -->
<xsl:when test="starts-with(saxon:systemId(), 'file:/')
and substring(saxon:systemId(), 7, 2) != '//'">
<xsl:value-of
select="concat('file:///',
substring-after(saxon:systemId(),
'file:/'))"/>
</xsl:when>
<xsl:when test="starts-with(saxon:systemId(), 'file:')">
<xsl:value-of select="substring-after(saxon:systemId(),
'file:')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="saxon:systemId()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:with-param>
</xsl:call-template>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</xsl:copy>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="*" mode="stripNS">
<xsl:choose>
<xsl:when test="self::ng:* or self::db:*">
<xsl:element name="{local-name(.)}">
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</xsl:element>
</xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</xsl:copy>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="db:info" mode="stripNS">
<xsl:variable name="info">
<xsl:choose>
<xsl:when test="parent::db:article
|parent::db:appendix
|parent::db:bibliography
|parent::db:book
|parent::db:chapter
|parent::db:glossary
|parent::db:index
|parent::db:part
|parent::db:preface
|parent::db:refentry
|parent::db:reference
|parent::db:refsect1
|parent::db:refsect2
|parent::db:refsect3
|parent::db:refsection
|parent::db:refsynopsisdiv
|parent::db:sect1
|parent::db:sect2
|parent::db:sect3
|parent::db:sect4
|parent::db:sect5
|parent::db:section
|parent::db:setindex
|parent::db:set
|parent::db:slides
|parent::db:sidebar">
<xsl:value-of select="local-name(parent::*)"/>
<xsl:text>info</xsl:text>
</xsl:when>
<xsl:when test="parent::db:audioobject
|parent::db:imageobject
|parent::db:inlinemediaobject
|parent::db:mediaobject
|parent::db:mediaobjectco
|parent::db:textobject
|parent::db:videoobject">
<xsl:text>objectinfo</xsl:text>
</xsl:when>
<xsl:otherwise>blockinfo</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:element name="{$info}">
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</xsl:element>
<xsl:if test="(not(../db:title) and not(../ng:title))
and ($info = 'prefaceinfo'
or $info = 'chapterinfo'
or $info = 'sectioninfo'
or $info = 'sect1info'
or $info = 'sect2info'
or $info = 'sect3info'
or $info = 'sect4info'
or $info = 'sect5info'
or $info = 'refsectioninfo'
or $info = 'refsect1info'
or $info = 'refsect2info'
or $info = 'refsect3info'
or $info = 'blockinfo'
or $info = 'appendixinfo')">
<xsl:apply-templates select="db:title|ng:title" mode="stripNS"/>
</xsl:if>
</xsl:template>
<xsl:template match="ng:link|db:link" mode="stripNS">
<xsl:variable xmlns:xlink="http://www.w3.org/1999/xlink";
name="href" select="@xlink:href|@href"/>
<xsl:choose>
<xsl:when test="$href != '' and not(starts-with($href,'#'))">
<ulink url="{$href}">
<xsl:for-each select="@*">
<xsl:if test="local-name(.) != 'href'
and name(.) != 'version'
and name(.) != 'xml:id'">
<xsl:copy/>
</xsl:if>
</xsl:for-each>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</ulink>
</xsl:when>
<xsl:when test="$href != '' and starts-with($href,'#')">
<link linkend="{substring-after($href,'#')}">
<xsl:for-each select="@*">
<xsl:if test="local-name(.) != 'href'
and name(.) != 'version'
and name(.) != 'xml:id'">
<xsl:copy/>
</xsl:if>
</xsl:for-each>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</link>
</xsl:when>
<xsl:otherwise>
<link>
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</link>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="ng:tag|db:tag" mode="stripNS">
<sgmltag>
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:apply-templates mode="stripNS"/>
</sgmltag>
</xsl:template>
<xsl:template match="ng:textdata|db:textdata
|ng:imagedata|db:imagedata
|ng:videodata|db:videodata
|ng:audiodata|db:audiodata" mode="stripNS">
<xsl:element name="{local-name(.)}">
<xsl:copy-of select="@*[not(name(.) = 'xml:id')
and not(name(.) = 'version')]"/>
<xsl:if test="@xml:id">
<xsl:attribute name="id">
<xsl:value-of select="@xml:id"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates mode="stripNS"/>
</xsl:element>
</xsl:template>
<xsl:template name="systemIdToBaseURI">
<xsl:param name="systemId" select="''"/>
<xsl:if test="contains($systemId,'/')">
<xsl:value-of select="substring-before($systemId,'/')"/>
<xsl:text>/</xsl:text>
<xsl:call-template name="systemIdToBaseURI">
<xsl:with-param name="systemId"
select="substring-after($systemId,'/')"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:template match="comment()|processing-instruction()|text()" mode="stripNS">
<xsl:copy/>
</xsl:template>
<xsl:template match="/" priority="-1">
<xsl:choose>
<xsl:when test="function-available('exsl:node-set')
and (*/self::ng:* or */self::db:*)">
<xsl:message>Stripping NS from DocBook 5/NG document.</xsl:message>
<xsl:variable name="nons">
<xsl:apply-templates mode="stripNS"/>
</xsl:variable>
<xsl:message>Processing stripped document.</xsl:message>
<xsl:apply-templates select="exsl:node-set($nons)"/>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="@* | node()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
S/MIME Cryptographic Signature
[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [List Home]