OASIS Mailing List ArchivesView the OASIS mailing list archive below
or browse/search using MarkMail.

 


Help: OASIS Mailing Lists Help | MarkMail Help

docbook-apps message

[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [List Home]


Subject: Re: [docbook-apps] Would like to add Copyright info to footer content


Hi Gabriela,

In your template, this bit generates the copyright text:

<xsl:apply-templates select="/book/bookinfo/copyright[1]"
ÂÂÂÂÂÂÂÂÂÂÂÂÂÂÂ mode="titlepage.mode"/>

There is a template matching on copyright in mode="titlepage.mode" in the XSL file "titlepage.xsl" in the html directory of the docbook distribution. You can copy that template to your customization layer and rearrange it as needed.

The call to the template named "gentext" generates the word "Copyright" in the appropriate language, and the call to the template named "dingbat" generates the copyright symbol.

Bob Stayton
Sagehill Enterprises
bobs@sagehill.net
On 8/23/2018 7:29 AM, Gabriela Simonka wrote:
Thank you both!

Now I am trying to set the content of the copyright notice so that it appears as follows:

 INRO, 1983-2018

But what appears instead is

Copyright  1983-2018 INRO

Changing the order of the year and holder tags seems to have no effect. How do I customize this?

Gabriela

On Tue, Aug 14, 2018 at 12:10 PM, Bob Stayton <bobs@sagehill.net> wrote:

Indeed, this is the customization I used in my stylesheet to generate that HTML footer in DocBook XSL: The Complete Guide:

<xsl:template name="user.footer.content">
 <table class="copyright" border="0" cellpadding="0" cellspacing="0" width="100%">
ÂÂÂÂÂÂÂÂÂ <col width="33%"/>
ÂÂÂÂÂÂÂÂÂ <col width="33%"/>
ÂÂÂÂÂÂÂÂÂ <col width="33%"/>
 <tr>
ÂÂÂÂÂÂÂÂÂ <td>DocBook XSL: The Complete Guide - 4th Edition</td>
ÂÂÂÂÂÂÂÂÂ <td align="center"><a href="" class="m_348308403063346945moz-txt-link-rfc2396E" href="http://www.sagehill.net/book-description.html" target="_blank" moz-do-not-send="true">"http://www.sagehill.net/book-description.html">PDF version available</a></td>
ÂÂÂ <td align="right">
ÂÂÂÂÂÂÂÂÂÂÂÂ <xsl:apply-templates select="/book/bookinfo/copyright[1]"
ÂÂÂÂÂÂÂÂÂÂÂÂÂÂÂ mode="titlepage.mode"/>
ÂÂÂ </td>
 </tr></table>
</xsl:template>

If you are using DocBook 5 then you will need to add the namespace prefix to the element names.

Bob Stayton
Sagehill Enterprises
bobs@sagehill.net
On 8/14/2018 8:37 AM, Peter Desjardins wrote:
Hi, Gabriela.

Try customizing the user.footer.content template? This page gives an
example that includes copyright information:

  http://www.sagehill.net/docbookxsl/HTMLHeaders.html#HeaderExtras

You could add HTML in that template until the copyright information
appears where you want it.

Good luck!

Peter

On Tue, Aug 14, 2018 at 11:23 AM, Gabriela Simonka
<gabriela@inrosoftware.com> wrote:
Hello,

I would like to modify our footer content template to include copyright info
above the navigation "Next " icon, similar to how it appears on the DocBook
XSL: The Complete Guide pages.

I believe I would have to add a third row to include the content that I
would want to add; just not sure how to do it.

Would appreciate some assistance.

Our current template is as follows:

<xsl:template name="footer.navigation">
  <xsl:param name="prev" select="/foo"/>
  <xsl:param name="next" select="/foo"/>
  <xsl:param name="nav.context"/>
  <xsl:variable name="home" select="/*[1]"/>
  <xsl:variable name="up" select="parent::*"/>
  <xsl:variable name="row1" select="count($prev) &gt; 0
                                    or count($up) &gt; 0
                                    or count($next) &gt; 0"/>
  <xsl:variable name="row2" select="($prev and $navig.showtitles != 0)
                                    or (generate-id($home) != generate-id(.)
                                        or $nav.context = 'toc')
                                    or ($chunk.tocs.and.lots != 0
                                        and $nav.context != 'toc')
                                    or ($next and $navig.showtitles != 0)"/>
  <xsl:if test="$suppress.navigation = '0' and $suppress.footer.navigation =
'0'">
   <div class="navfooter">
    <xsl:if test="$footer.rule != 0">
     <hr/>
    </xsl:if>
    <xsl:if test="$row1 or $row2">
     <table width="100%" summary="Navigation footer">
      <xsl:if test="$row1">
       <tr>
        <td width="40%" align="left">
         <xsl:if test="count($prev)>0">
          <a accesskey="p">
           <xsl:attribute name="href">
            <xsl:call-template name="href.target">
             <xsl:with-param name="object" select="$prev"/>
            </xsl:call-template>
           </xsl:attribute>
           <xsl:call-template name="navig.content">
            <xsl:with-param name="direction" select="'prev'"/>
           </xsl:call-template>
          </a>
         </xsl:if>
         <xsl:text>&#160;</xsl:text>
        </td>
        <td width="20%" align="center">
         <xsl:choose>
          <xsl:when test="count($up)&gt;0
                         and generate-id($up) != generate-id($home)">
           <a accesskey="u">
            <xsl:attribute name="href">
             <xsl:call-template name="href.target">
              <xsl:with-param name="object" select="$up"/>
             </xsl:call-template>
            </xsl:attribute>
            <xsl:call-template name="navig.content">
             <xsl:with-param name="direction" select="'up'"/>
            </xsl:call-template>
           </a>
          </xsl:when>
          <xsl:otherwise>&#160;</xsl:otherwise>
         </xsl:choose>
        </td>
        <td width="40%" align="right">
         <xsl:text>&#160;</xsl:text>
         <xsl:if test="count($next)>0">
          <a accesskey="n">
           <xsl:attribute name="href">
            <xsl:call-template name="href.target">
             <xsl:with-param name="object" select="$next"/>
            </xsl:call-template>
           </xsl:attribute>
           <xsl:call-template name="navig.content">
            <xsl:with-param name="direction" select="'next'"/>
           </xsl:call-template>
          </a>
         </xsl:if>
        </td>
       </tr>
      </xsl:if>
      <xsl:if test="$row2">
       <tr>
        <td width="40%" align="left" valign="top">
         <xsl:if test="$navig.showtitles != 0">
          <small>
           <xsl:apply-templates select="$prev" mode="object.title.markup"/>
          </small>
         </xsl:if>
         <xsl:text>&#160;</xsl:text>
        </td>
        <td width="20%" align="center">
         <xsl:choose>
          <xsl:when test="$home != . or $nav.context = 'toc'">
           <a accesskey="h">
            <xsl:attribute name="href">
             <xsl:call-template name="href.target">
              <xsl:with-param name="object" select="$home"/>
             </xsl:call-template>
            </xsl:attribute>
            <xsl:call-template name="navig.content">
             <xsl:with-param name="direction" select="'home'"/>
            </xsl:call-template>
           </a>
           <xsl:if test="$chunk.tocs.and.lots != 0 and $nav.context !=
'toc'">
            <xsl:text>&#160;|&#160;</xsl:text>
           </xsl:if>
          </xsl:when>
          <xsl:otherwise>&#160;</xsl:otherwise>
         </xsl:choose>
         <xsl:if test="$chunk.tocs.and.lots != 0 and $nav.context != 'toc'">
          <a accesskey="t">
           <xsl:attribute name="href">
            <xsl:apply-templates select="/*[1]"
                                           mode="recursive-chunk-filename">
             <xsl:with-param name="recursive" select="true()"/>
            </xsl:apply-templates>
            <xsl:text>-toc</xsl:text>
            <xsl:value-of select="$html.ext"/>
           </xsl:attribute>
           <xsl:call-template name="gentext">
            <xsl:with-param name="key" select="'nav-toc'"/>
           </xsl:call-template>
          </a>
         </xsl:if>
        </td>
        <td width="40%" align="right" valign="top">
         <xsl:text>&#160;</xsl:text>
         <xsl:if test="$navig.showtitles != 0">
          <small>
           <xsl:apply-templates select="$next" mode="object.title.markup"/>
          </small>
         </xsl:if>
        </td>
       </tr>
      </xsl:if>
     </table>
    </xsl:if>
   </div>
  </xsl:if>
 </xsl:template>

Thanks!
Gabriela

--
Gabriela Simonka
Technical Writer, INRO
+1 514.369.2023

---------------------------------------------------------------------
To unsubscribe, e-mail: docbook-apps-unsubscribe@lists.oasis-open.org
For additional commands, e-mail: docbook-apps-help@lists.oasis-open.org







--
Gabriela Simonka
Technical Writer, INRO
+1 514.369.2023




[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [List Home]