[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [List Home]
Subject: [OASIS Issue Tracker] Commented: (OFFICE-1868) Public Comment:custom shape interop issues
[ http://tools.oasis-open.org/issues/browse/OFFICE-1868?page=com.atlassian.jira.plugin.system.issuetabpanels:comment-tabpanel&focusedCommentId=15966#action_15966 ]
Michael Brauer commented on OFFICE-1868:
----------------------------------------
"sets of subpaths" occurs in the comment, not in the specification.
Regarding the 2nd question. I think that's what we mean, but what about:
"If command is immediately followed by one ore more commands that uses the same command character, the repeated command characters except the first one may be omitted."
I may also prove an EBNF grammar now. Its:
enhanced-path::= commandsequence?
commandsequence::= command ( sep? command )*
command::= cA | cB | cC | cF | cL | cM | cN | cQ | cS | cT | cU | cV | cW | cX | cY | cZ
cA::= 'A' sep? paraseq8 ( sep paraseq8 )*
cB::= 'B' sep? paraseq8 ( sep paraseq8 )*
cC::= 'C' sep? paraseq6 ( sep paraseq6 )*
cF::= 'F'
cL::= 'L' sep? paraseq2 ( sep paraseq2 )*
cM::= 'M' sep? paraseq2 ( sep paraseq2 )*
cN::= 'N'
cQ::= 'Q' sep? paraseq4 ( sep paraseq4 )*
cS::= 'S'
cT::= 'T' sep? paraseq6 ( sep paraseq6 )*
cU::= 'U' sep? paraseq6 ( sep paraseq6 )*
cV::= 'V' sep? paraseq8 ( sep paraseq8 )*
cW::= 'W' sep? paraseq8 ( sep paraseq8 )*
cX::= 'X' sep? paraseq2 ( sep paraseq2 )*
cY::= 'Y' sep? paraseq2 ( sep paraseq2 )*
cZ::= 'Z'
paraseq2::= val sepval
paraseq4::= val sepval sepval sepval
paraseq6::= val sepval sepval sepval sepval sepval
paraseq8::= val sepval sepval sepval sepval sepval sepval sepval
sep::= wsseq | ( wsseq? ',' wsseq? )
wsseq::= ' '+
val::= formula | modifier | number
sepval::= ( sep? formula ) | ( sep? modifier ) | ( sep number )
formula::= '?' name
modifier::= '$' integer
number::= sign? fractional | sign? integer
fractional::= integer? '.' integer | integer '.'
sign::= '+'| '-'
integer::= [0-9]+
name ::= [^?$ ]+
> Public Comment: custom shape interop issues
> -------------------------------------------
>
> Key: OFFICE-1868
> URL: http://tools.oasis-open.org/issues/browse/OFFICE-1868
> Project: OASIS Open Document Format for Office Applications (OpenDocument) TC
> Issue Type: Bug
> Components: Graphics
> Reporter: Robert Weir
> Assignee: Patrick Durusau
> Fix For: ODF 1.2
>
>
> Copied from office-comment list
> Original author: Chris Nokleberg
> Original date: 21 Jan 2006
> Original URL: http://lists.oasis-open.org/archives/opendocument-users/200601/msg00015.html
--
This message is automatically generated by JIRA.
-
If you think it was sent incorrectly contact one of the administrators: http://tools.oasis-open.org/issues/secure/Administrators.jspa
-
For more information on JIRA, see: http://www.atlassian.com/software/jira
[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [List Home]