[OASIS Issue Tracker] (AMQP-108) Incorporate ABNF "inherited" references

[OASIS Issues Tracker <workgroup_mailer@lists.oasis-open.org>]

Brian Raymor created AMQP-108:
---------------------------------

             Summary: Incorporate ABNF "inherited" references
                 Key: AMQP-108
                 URL: https://issues.oasis-open.org/browse/AMQP-108
             Project: OASIS Advanced Message Queuing Protocol (AMQP) TC
          Issue Type: Improvement
          Components: Claims Based Security
    Affects Versions: cbs-WD03
            Reporter: Brian Raymor
            Assignee: Brian Raymor
            Priority: Trivial
             Fix For: cbs-WD04


There are a number of ABNF definitions "inherited" from specific RFC(s). These definitions need to be incorporated/duplicated into CBS in some fashion.

References:

https://tools.ietf.org/html/rfc5234#appendix-B

DIGIT          =  %x30-39

https://tools.ietf.org/html/rfc3339#section-5.6

date-fullyear   = 4DIGIT
date-month      = 2DIGIT  ; 01-12
date-mday       = 2DIGIT  ; 01-28, 01-29, 01-30, 01-31 based on
                             ; month/year
time-hour       = 2DIGIT  ; 00-23
time-minute     = 2DIGIT  ; 00-59
time-second     = 2DIGIT  ; 00-58, 00-59, 00-60 based on leap second
                             ; rules
time-secfrac    = "." 1*DIGIT
time-numoffset  = ("+" / "-") time-hour ":" time-minute
time-offset     = "Z" / time-numoffset

partial-time    = time-hour ":" time-minute ":" time-second
                     [time-secfrac]
full-date       = date-fullyear "-" date-month "-" date-mday
full-time       = partial-time time-offset

date-time       = full-date "T" full-time

https://tools.ietf.org/html/rfc3629#section-4

UTF8-octets = *( UTF8-char )
UTF8-char   = UTF8-1 / UTF8-2 / UTF8-3 / UTF8-4
UTF8-1      = %x00-7F ; NEED TO CHANGE THIS to 0x01-7F TO EXCLUDE NUL?
UTF8-2      = %xC2-DF UTF8-tail

UTF8-3      = %xE0 %xA0-BF UTF8-tail / %xE1-EC 2( UTF8-tail ) /
              %xED %x80-9F UTF8-tail / %xEE-EF 2( UTF8-tail )
UTF8-4      = %xF0 %x90-BF 2( UTF8-tail ) / %xF1-F3 3( UTF8-tail ) /
              %xF4 %x80-8F 2( UTF8-tail )
UTF8-tail   = %x80-BF

https://tools.ietf.org/html/rfc3987#section-2.2

dec-octet      = DIGIT             ; 0-9
               / %x31-39 DIGIT     ; 10-99
               / "1" 2DIGIT        ; 100-199
               / "2" %x30-34 DIGIT ; 200-249
               / "25" %x30-35      ; 250-255






--
This message was sent by Atlassian JIRA
(v6.2.2#6258)