[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [Elist Home]
Subject: Re: DOCBOOK-APPS: Table seps with XSL-FO
If somebody had the same problem, I have found : Just put the "frame" attribute to "all" in the "table" element. Then rows / cols seps are ok in both HTML and PDF. Although in the def. guide I understood the frame table att. was intended to the table border itself, not the entrys seps. And another tip for tables in PDF with FOP 0.20.3 : "table-and-caption" and "caption" elements in FO (comming from XML tables titles) are not supported by FOP, so no tables can output in PDF. So to correct this, in the ebnf.xsl and formal.xsl comment the "table-and-caption" and "caption" elements, but not the "table" element inside. Then enjoy nice tables in PDF. Enclosed are the corrected stylesheets. -- Hugues Pichereau - Webmaster Telemedicine Technologies Hugues Pichereau wrote: > Hello, > > I use DocBook XML with Norman Walsh's XSL stylesheets, both for HTML and > PDF output. > - for HTML : XSL 1.45 (cause bug in 1.48 with chunk.xsl), with Xalan J 2 > > - for FO/ PDF : XSL 1.48 with Xalan J 2 and FOP 0.20.3 > > With no rowsep or colsep attributes, tables render ok in HTML, but there > are no row or column separators in PDF. I've tried to put rowsep and > colsep to 1, for <table> and <tgroup> elements, but no seps in PDF. Only > when each <entry> has its rowsep and colsep the separators are output in > PDF, but it's quite boring to do. > > Any idea ? > > -- > Hugues Pichereau - Webmaster > Telemedicine Technologies
<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
exclude-result-prefixes="doc"
version='1.0'>
<!-- ********************************************************************
$Id: ebnf.xsl,v 1.2 2001/11/12 20:41:45 nwalsh Exp $
********************************************************************
This file is part of the XSL DocBook Stylesheet distribution.
See ../README or http://nwalsh.com/docbook/xsl/ for copyright
and other information.
******************************************************************** -->
<doc:reference xmlns="">
<referenceinfo>
<releaseinfo role="meta">
$Id: ebnf.xsl,v 1.2 2001/11/12 20:41:45 nwalsh Exp $
</releaseinfo>
<author><surname>Walsh</surname>
<firstname>Norman</firstname></author>
<copyright><year>1999</year><year>2000</year><year>2001</year>
<holder>Norman Walsh</holder>
</copyright>
</referenceinfo>
<title>HTML EBNF Reference</title>
<partintro>
<section><title>Introduction</title>
<para>This is technical reference documentation for the DocBook XSL
Stylesheets; it documents (some of) the parameters, templates, and
other elements of the stylesheets.</para>
<para>This reference describes the templates and parameters relevant
to formatting EBNF markup.</para>
<para>This is not intended to be <quote>user</quote> documentation.
It is provided for developers writing customization layers for the
stylesheets, and for anyone who's interested in <quote>how it
works</quote>.</para>
<para>Although I am trying to be thorough, this documentation is known
to be incomplete. Don't forget to read the source, too :-)</para>
</section>
</partintro>
</doc:reference>
<!-- ==================================================================== -->
<xsl:template match="productionset">
<xsl:variable name="id"><xsl:call-template name="object.id"/></xsl:variable>
<xsl:choose>
<xsl:when test="title">
<!--
<fo:table-and-caption id="{$id}"
xsl:use-attribute-sets="formal.object.properties">
<fo:table-caption>
-->
<fo:block space-before="15pt" font-weight="bold" xsl:use-attribute-sets="formal.title.properties">
<xsl:apply-templates select="." mode="object.title.markup"/>
</fo:block>
<!--
</fo:table-caption>
-->
<fo:table table-layout="fixed" width="100%">
<fo:table-body>
<xsl:apply-templates select="production|productionrecap"/>
</fo:table-body>
</fo:table>
<!--
</fo:table-and-caption>
-->
</xsl:when>
<xsl:otherwise>
<fo:table table-layout="fixed" width="100%">
<fo:table-body>
<xsl:apply-templates select="production|productionrecap"/>
</fo:table-body>
</fo:table>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="productionset/title">
<!-- suppressed -->
</xsl:template>
<xsl:template match="production">
<xsl:param name="recap" select="false()"/>
<xsl:variable name="id"><xsl:call-template name="object.id"/></xsl:variable>
<fo:table-row>
<fo:table-cell width="3%">
<fo:block text-align="start">
<xsl:text>[</xsl:text>
<xsl:number count="production" level="any"/>
<xsl:text>]</xsl:text>
</fo:block>
</fo:table-cell>
<fo:table-cell width="10%">
<fo:block text-align="end">
<xsl:choose>
<xsl:when test="$recap">
<fo:basic-link internal-destination="{$id}"
xsl:use-attribute-sets="xref.properties">
<xsl:apply-templates select="lhs"/>
</fo:basic-link>
</xsl:when>
<xsl:otherwise>
<fo:wrapper id="{$id}">
<xsl:apply-templates select="lhs"/>
</fo:wrapper>
</xsl:otherwise>
</xsl:choose>
</fo:block>
</fo:table-cell>
<fo:table-cell width="5%">
<fo:block text-align="center">
<fo:inline font-family="{$monospace.font.family}">
<xsl:text>::=</xsl:text>
</fo:inline>
</fo:block>
</fo:table-cell>
<fo:table-cell width="52%">
<fo:block>
<xsl:apply-templates select="rhs"/>
</fo:block>
</fo:table-cell>
<fo:table-cell width="30%" border-start-width="3pt">
<fo:block text-align="start">
<xsl:choose>
<xsl:when test="rhs/lineannotation|constraint">
<xsl:apply-templates select="rhs/lineannotation" mode="rhslo"/>
<xsl:apply-templates select="constraint"/>
</xsl:when>
<xsl:otherwise>
<xsl:text> </xsl:text>
</xsl:otherwise>
</xsl:choose>
</fo:block>
</fo:table-cell>
</fo:table-row>
</xsl:template>
<xsl:template match="productionrecap">
<xsl:variable name="targets" select="key('id',@linkend)"/>
<xsl:variable name="target" select="$targets[1]"/>
<xsl:if test="count($targets)=0">
<xsl:message>
<xsl:text>Error: no ID for productionrecap linkend: </xsl:text>
<xsl:value-of select="@linkend"/>
<xsl:text>.</xsl:text>
</xsl:message>
</xsl:if>
<xsl:if test="count($targets)>1">
<xsl:message>
<xsl:text>Warning: multiple "IDs" for productionrecap linkend: </xsl:text>
<xsl:value-of select="@linkend"/>
<xsl:text>.</xsl:text>
</xsl:message>
</xsl:if>
<xsl:apply-templates select="$target">
<xsl:with-param name="recap" select="true()"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="lhs">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="rhs">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="nonterminal">
<xsl:variable name="linkend">
<xsl:call-template name="xpointer.idref">
<xsl:with-param name="xpointer" select="@def"/>
</xsl:call-template>
</xsl:variable>
<xsl:call-template name="check.id.unique">
<xsl:with-param name="linkend" select="$linkend"/>
</xsl:call-template>
<xsl:call-template name="check.idref.targets">
<xsl:with-param name="linkend" select="$linkend"/>
<xsl:with-param name="element-list">production</xsl:with-param>
</xsl:call-template>
<!-- If you don't provide content, you can't point outside this doc. -->
<xsl:choose>
<xsl:when test="*|text()"><!--nop--></xsl:when>
<xsl:otherwise>
<xsl:if test="$linkend = ''">
<xsl:message>
<xsl:text>Non-terminals with no content must point to </xsl:text>
<xsl:text>production elements in the current document.</xsl:text>
</xsl:message>
<xsl:message>
<xsl:text>Invalid xpointer for empty nt: </xsl:text>
<xsl:value-of select="@def"/>
</xsl:message>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
<xsl:variable name="href">
<xsl:choose>
<xsl:when test="$linkend != ''">
<xsl:variable name="targets" select="key('id',$linkend)"/>
<xsl:variable name="target" select="$targets[1]"/>
<xsl:call-template name="object.id">
<xsl:with-param name="object" select="$target"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="@def"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<fo:basic-link internal-destination="{$href}"
xsl:use-attribute-sets="xref.properties">
<xsl:choose>
<xsl:when test="*|text()">
<xsl:apply-templates/>
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="$linkend != ''">
<xsl:variable name="targets" select="key('id',$linkend)"/>
<xsl:variable name="target" select="$targets[1]"/>
<xsl:apply-templates select="$target/lhs"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>???</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</fo:basic-link>
</xsl:template>
<xsl:template match="rhs/lineannotation">
<!--nop-->
</xsl:template>
<xsl:template match="rhs/lineannotation" mode="rhslo">
<xsl:text>/* </xsl:text>
<xsl:apply-templates/>
<xsl:text> */</xsl:text>
</xsl:template>
<xsl:template match="constraint">
<xsl:call-template name="check.id.unique">
<xsl:with-param name="linkend" select="@linkend"/>
</xsl:call-template>
<xsl:call-template name="check.idref.targets">
<xsl:with-param name="linkend" select="@linkend"/>
<xsl:with-param name="element-list">constraintdef</xsl:with-param>
</xsl:call-template>
<xsl:variable name="href">
<xsl:variable name="targets" select="key('id',@linkend)"/>
<xsl:variable name="target" select="$targets[1]"/>
<xsl:call-template name="object.id">
<xsl:with-param name="object" select="$target"/>
</xsl:call-template>
</xsl:variable>
<xsl:if test="preceding-sibling::constraint">
<fo:inline linefeed-treatment="preserve">
</fo:inline>
</xsl:if>
<xsl:text>[ </xsl:text>
<xsl:choose>
<xsl:when test="@role">
<xsl:value-of select="@role"/>
<xsl:text>: </xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:variable name="targets" select="key('id',@linkend)"/>
<xsl:variable name="target" select="$targets[1]"/>
<xsl:if test="$target/@role">
<xsl:value-of select="$target/@role"/>
<xsl:text>: </xsl:text>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
<fo:basic-link internal-destination="{$href}"
xsl:use-attribute-sets="xref.properties">
<xsl:variable name="targets" select="key('id',@linkend)"/>
<xsl:variable name="target" select="$targets[1]"/>
<xsl:apply-templates select="$target" mode="title.markup"/>
</fo:basic-link>
<xsl:text> ]</xsl:text>
</xsl:template>
<xsl:template match="constraintdef">
<xsl:variable name="id"><xsl:call-template name="object.id"/></xsl:variable>
<fo:block id="{$id}">
<xsl:apply-templates/>
</fo:block>
</xsl:template>
<xsl:template match="constraintdef/title">
<fo:block font-weight="bold">
<xsl:apply-templates/>
</fo:block>
</xsl:template>
<!-- ==================================================================== -->
</xsl:stylesheet>
<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
version='1.0'>
<!-- ********************************************************************
$Id: formal.xsl,v 1.7 2001/12/01 20:01:02 nwalsh Exp $
********************************************************************
This file is part of the XSL DocBook Stylesheet distribution.
See ../README or http://nwalsh.com/docbook/xsl/ for copyright
and other information.
******************************************************************** -->
<xsl:template name="formal.object">
<xsl:variable name="id">
<xsl:call-template name="object.id"/>
</xsl:variable>
<fo:block id="{$id}"
xsl:use-attribute-sets="formal.object.properties">
<xsl:call-template name="formal.object.heading"/>
<xsl:apply-templates/>
</fo:block>
</xsl:template>
<xsl:template name="formal.object.heading">
<xsl:param name="title"></xsl:param>
<fo:block xsl:use-attribute-sets="formal.title.properties">
<xsl:apply-templates select="." mode="object.title.markup"/>
</fo:block>
</xsl:template>
<xsl:template name="informal.object">
<fo:block>
<xsl:apply-templates/>
</fo:block>
</xsl:template>
<xsl:template name="semiformal.object">
<xsl:choose>
<xsl:when test="./title">
<xsl:call-template name="formal.object"/>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="informal.object"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="figure|example">
<xsl:call-template name="formal.object"/>
</xsl:template>
<xsl:template name="table.frame">
<xsl:variable name="frame">
<xsl:choose>
<xsl:when test="@frame">
<xsl:value-of select="@frame"/>
</xsl:when>
<xsl:otherwise>all</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$frame='all'">
<xsl:attribute name="border-left-style">solid</xsl:attribute>
<xsl:attribute name="border-right-style">solid</xsl:attribute>
<xsl:attribute name="border-top-style">solid</xsl:attribute>
<xsl:attribute name="border-bottom-style">solid</xsl:attribute>
</xsl:when>
<xsl:when test="$frame='bottom'">
<xsl:attribute name="border-left-style">none</xsl:attribute>
<xsl:attribute name="border-right-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">solid</xsl:attribute>
</xsl:when>
<xsl:when test="$frame='sides'">
<xsl:attribute name="border-left-style">solid</xsl:attribute>
<xsl:attribute name="border-right-style">solid</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">none</xsl:attribute>
</xsl:when>
<xsl:when test="$frame='top'">
<xsl:attribute name="border-left-style">none</xsl:attribute>
<xsl:attribute name="border-right-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">solid</xsl:attribute>
<xsl:attribute name="border-bottom-style">none</xsl:attribute>
</xsl:when>
<xsl:when test="$frame='topbot'">
<xsl:attribute name="border-left-style">none</xsl:attribute>
<xsl:attribute name="border-right-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">solid</xsl:attribute>
<xsl:attribute name="border-bottom-style">solid</xsl:attribute>
</xsl:when>
<xsl:when test="$frame='none'">
<xsl:attribute name="border-left-style">none</xsl:attribute>
<xsl:attribute name="border-right-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">none</xsl:attribute>
</xsl:when>
<xsl:otherwise>
<xsl:message>
<xsl:text>Impossible frame on table: </xsl:text>
<xsl:value-of select="$frame"/>
</xsl:message>
<xsl:attribute name="border-left-style">none</xsl:attribute>
<xsl:attribute name="border-right-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">none</xsl:attribute>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="table">
<xsl:variable name="id">
<xsl:call-template name="object.id"/>
</xsl:variable>
<xsl:variable name="prop-columns"
select=".//colspec[contains(@colwidth, '*')]"/>
<fo:block>
<xsl:attribute name="span">
<xsl:choose>
<xsl:when test="@pgwide=1">all</xsl:when>
<xsl:otherwise>none</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<!--
<fo:table-and-caption id="{$id}"
xsl:use-attribute-sets="formal.object.properties"
keep-together.within-column="1">
<fo:table-caption>
-->
<fo:block space-before="15pt" font-weight="bold" xsl:use-attribute-sets="formal.title.properties">
<xsl:apply-templates select="." mode="object.title.markup"/>
</fo:block>
<!--
</fo:table-caption>
-->
<fo:table>
<xsl:call-template name="table.frame"/>
<xsl:if test="count($prop-columns) != 0">
<xsl:attribute name="table-layout">fixed</xsl:attribute>
</xsl:if>
<xsl:apply-templates select="tgroup"/>
</fo:table>
<!--
</fo:table-and-caption>
-->
</fo:block>
</xsl:template>
<xsl:template match="equation">
<xsl:call-template name="semiformal.object"/>
</xsl:template>
<xsl:template match="figure/title"></xsl:template>
<xsl:template match="table/title"></xsl:template>
<xsl:template match="example/title"></xsl:template>
<xsl:template match="equation/title"></xsl:template>
<xsl:template match="informalfigure">
<xsl:call-template name="informal.object"/>
</xsl:template>
<xsl:template match="informalexample">
<xsl:call-template name="informal.object"/>
</xsl:template>
<xsl:template match="informaltable">
<xsl:variable name="prop-columns"
select=".//colspec[contains(@colwidth, '*')]"/>
<fo:block>
<xsl:attribute name="span">
<xsl:choose>
<xsl:when test="@pgwide=1">all</xsl:when>
<xsl:otherwise>none</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<fo:table>
<xsl:call-template name="table.frame"/>
<xsl:if test="count($prop-columns) != 0">
<xsl:attribute name="table-layout">fixed</xsl:attribute>
</xsl:if>
<xsl:apply-templates select="tgroup"/>
</fo:table>
</fo:block>
</xsl:template>
<xsl:template match="informalequation">
<xsl:call-template name="informal.object"/>
</xsl:template>
</xsl:stylesheet>
[Date Prev] | [Thread Prev] | [Thread Next] | [Date Next] -- [Date Index] | [Thread Index] | [Elist Home]
Powered by eList eXpress LLC