Template for side-by-side lay-out adjusted for bridgeheads [was: Left-aligning section titles with body text]

[Erik Leunissen <e.leunissen@hccnet.nl>]

On 18/10/13 00:10, Bob Stayton wrote:
> Yes, it is described in this section of my book:
>
> http://www.sagehill.net/docbookxsl/SideBySide.html

I've adjusted that template to account for bridgeheads rendered as a 
certain section level. For anyone to use at own risk.

Regards,

Erik Leunissen
--
<xsl:template name="section.heading">
  <xsl:param name="level" select="1"/>
  <xsl:param name="marker" select="1"/>
  <xsl:param name="title"/>
  <xsl:param name="marker.title"/>

  <xsl:variable name="title.block">
    <xsl:choose>
      <xsl:when test="self::d:bridgehead">
        <xsl:value-of select="$title"/>
      </xsl:when>
      <xsl:otherwise>
        <fo:list-block start-indent="0mm"
                provisional-distance-between-starts="{$body.start.indent}"
                provisional-label-separation="5mm">
          <fo:list-item>
            <fo:list-item-label end-indent="label-end()" 
text-align="start">
              <fo:block>
                <xsl:apply-templates select="parent::*" 
mode="label.markup"/>
              </fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()" 
text-align="start">
              <fo:block>
                <xsl:apply-templates select="parent::*" 
mode="title.markup"/>
              </fo:block>
            </fo:list-item-body>
          </fo:list-item>
        </fo:list-block>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>

  <fo:block xsl:use-attribute-sets="section.title.properties">
    <xsl:if test="$marker != 0">
      <fo:marker marker-class-name="section.head.marker">
        <xsl:copy-of select="$marker.title"/>
      </fo:marker>
    </xsl:if>

    <xsl:choose>
      <xsl:when test="$level=1">
        <fo:block xsl:use-attribute-sets="section.title.level1.properties">
          <xsl:copy-of select="$title.block"/>
        </fo:block>
      </xsl:when>
      <xsl:when test="$level=2">
        <fo:block xsl:use-attribute-sets="section.title.level2.properties">
          <xsl:copy-of select="$title.block"/>
        </fo:block>
      </xsl:when>
      <xsl:when test="$level=5">
        <fo:block xsl:use-attribute-sets="section.title.level5.properties">
          <xsl:copy-of select="$title.block"/>
        </fo:block>
      </xsl:when>
      <!-- add more levels here -->
    </xsl:choose>
  </fo:block>
</xsl:template>

-- end of message --