DOCBOOK-APPS: Re: HTML meta description tags

[Norman Walsh <ndw@nwalsh.com>]

[ Follow-ups to docbook-apps, please ]

/ Aaron Isotton <aaron@isotton.com> was heard to say:
| Sorry, I don't understand. I just grepped through the docbook
| documentation for "user." but didn't find anything like that. Could
| you give me a pointer please?

Use this template in your customization layer. This will be part of
the next release. :-)

<xsl:param name="generate.meta.abstract" select="1"/>

<xsl:template name="head.content">
  <xsl:param name="node" select="."/>

  <title>
    <xsl:apply-templates select="$node" mode="object.title.markup.textonly"/>
  </title>

  <xsl:if test="$html.stylesheet">
    <link rel="stylesheet"
          href="{$html.stylesheet}"
          type="{$html.stylesheet.type}"/>
  </xsl:if>

  <xsl:if test="$link.mailto.url != ''">
    <link rev="made"
          href="{$link.mailto.url}"/>
  </xsl:if>

  <xsl:if test="$html.base != ''">
    <base href="{$html.base}"/>
  </xsl:if>

  <meta name="generator" content="DocBook XSL Stylesheets V{$VERSION}"/>

  <xsl:if test="$generate.meta.abstract != 0">
    <xsl:variable name="info" select="(articleinfo
                                      |bookinfo
                                      |prefaceinfo
                                      |chapterinfo
                                      |appendixinfo
                                      |sectioninfo
                                      |sect1info
                                      |sect2info
                                      |sect3info
                                      |sect4info
                                      |sect5info
                                      |referenceinfo
                                      |refentryinfo
                                      |partinfo
                                      |docinfo)[1]"/>
    <xsl:if test="$info and $info/abstract">
      <meta name="description">
        <xsl:attribute name="content">
          <xsl:for-each select="$info/abstract[1]/*">
            <xsl:value-of select="."/>
            <xsl:if test="position() &lt; last()">
              <xsl:text> </xsl:text>
            </xsl:if>
          </xsl:for-each>
        </xsl:attribute>
      </meta>
    </xsl:if>
  </xsl:if>

  <xsl:if test="ancestor-or-self::*[@status][1]/@status = 'draft'
                and $draft.watermark.image != ''">
    <style type="text/css"><xsl:text>
body { background-image: url("</xsl:text>
<xsl:value-of select="$draft.watermark.image"/><xsl:text>");
       background-repeat: no-repeat;
       background-position: top left;
       /* The following properties make the watermark "fixed" on the page. */
       /* I think that's just a bit too distracting for the reader... */
       /* background-attachment: fixed; */
       /* background-position: center center; */
</xsl:text>
    </style>
  </xsl:if>
  <xsl:apply-templates select="." mode="head.keywords.content"/>
</xsl:template>

                                        Be seeing you,
                                          norm

-- 
Norman Walsh <ndw@nwalsh.com>      | Our life gets as complicated as a
http://www.oasis-open.org/docbook/ | comedy as it goes on, but the
Chair, DocBook Technical Committee | complications get gradually
                                   | resolved: see that the curtain
                                   | comes down on a good
                                   | denouement.--Graci\'an