Re: [docbook-apps] Title placement and guibuttons with a frame around -> FO o...

[DeanNelson@aol.com]

Andreas

 

In regards to your second issue, have you tried "<keycap>Ok</keycap>" ?

 

Here is my stylesheet for keycaps and keycombo that will outline a phrase. This may work for you.

 

Regards,

Dean Nelson

 

*********************************************

 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns:fo="http://www.w3.org/1999/XSL/Format" >

 

    <xsl:template name="inline.sansseq">
        <xsl:param name="content">
            <xsl:apply-templates/>
        </xsl:param>
        <fo:inline font-family="{$sans.font.family}">
            <xsl:if test="@id">
                <xsl:attribute name="id">
                    <xsl:value-of select="@id"/>
                </xsl:attribute>
            </xsl:if>
            <xsl:if test="@dir">
                <xsl:attribute name="direction">
                    <xsl:choose>
                        <xsl:when test="@dir = 'ltr' or @dir = 'lro'">ltr</xsl:when>
                        <xsl:otherwise>rtl</xsl:otherwise>
                    </xsl:choose>
                </xsl:attribute>
            </xsl:if>
            <xsl:copy-of select="$content"/>
        </fo:inline>
    </xsl:template>
   
   
    <xsl:template match="keycap">
        <xsl:param name="key.contents" select="."/>
        <xsl:variable name="key.length" select="string-length($key.contents)"/>
       
        <fo:inline font-size="7.5pt" border="0.45pt solid black"
            padding-top="2pt" padding-bottom="0.75pt"
            padding-left="2pt" padding-right="2pt">

            <xsl:choose>
                <!-- NovDoc style keycaps -->
                <xsl:when test="@function">
                    <xsl:call-template name="inline.sansseq">
                        <xsl:with-param name="content">
                            <xsl:value-of select="@function"/>
                        </xsl:with-param>
                    </xsl:call-template>
                </xsl:when>
                <!-- regular Docbook Keycaps -->
                <xsl:otherwise>
                    <xsl:call-template name="inline.sansseq"/>
                </xsl:otherwise>
            </xsl:choose>
        </fo:inline>

    </xsl:template>

 

    <xsl:template match="keycombo">
        <xsl:variable name="action" select="@action"/>
        <xsl:variable name="joinchar">
            <xsl:choose>
                <xsl:when test="$action='seq'"> &#x2013; </xsl:when>
                <xsl:when test="$action='press'"> + </xsl:when>
                <xsl:when test="$action='other'"></xsl:when>
                <xsl:otherwise> + </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <xsl:for-each select="*">
            <xsl:if test="position()>1"><xsl:value-of select="$joinchar"/></xsl:if>
            <xsl:apply-templates select="."/>
        </xsl:for-each>
    </xsl:template>
  
</xsl:stylesheet>

**************************************

 

In a message dated 5/28/2008 8:25:44 A.M. Pacific Daylight Time, keh@parsytec.de writes:

Hey folks!

First:
I've tried to customize my title with the customization layer, but it
didn't solve my problem.
At the moment my title's are formatted like the following:

    1.   |This is my long title with a
    |linebreak!

And i want to create such like this:

    1.   |This is my long title with a
         |linebreak!

I've only found how i could insert special characters to the title. But
i think i must make a list/table or a floating block on the right or
such like this. But there is no way in the customization layer.


Second:
The second question i wrote a little time ago, but i received only an
answer for html output. So i try to describe it in detail.
I want a border/frame around my guibutton elements in the pdf. I used
docbook-xsl-1.72.0 with saxon 6.5.5 and xep 3.8.4 to render my pdf.
But i think it's a problem to describe it in fo. So i want an inline
element.
It should look like this (in one line!):
____
| OK |
|____|

Another example:
http://www.informatik.fh-wiesbaden.de/~werntges/home_t/proj/dbkcss102/ex
ample_inline.xml
Something like "ein GUI-Button" oder "eine Taste".

Big Thanks,

Andreas


---------------------------------------------------------------------
To unsubscribe, e-mail: docbook-apps-unsubscribe@lists.oasis-open.org
For additional commands, e-mail: docbook-apps-help@lists.oasis-open.org

---

Get trade secrets for amazing burgers. Watch "Cooking with Tyler Florence" on AOL Food.